# sed-Script zum Konvertieren von JANA in HTML mit Syntax highlight.
# z.B. sed -n -f jana2html.sed blabla.jana >> blabla.html
#
# Hinweis: Funktioniert NICHT zuverlässig in Zeilen, die Strings enthalten.
#
# Der generierte Output muss noch in <PRE> Tags eingeschlossen werden.
#
# Copyright (C) 2007 by Wiesner Thomas
#
# DISCLAIMER:
# Selbstverständlich bin ich nicht schuld, wenn das script irgendwas an einem
# Jana-Programm ruiniert. Oder sonst was löscht/kaputt macht.

# V0.2

# In/Out... Parameter Pfeile, welche ich normalerweise händisch einfüge,
# müssen hier zuerst durch HTML-Neutrale Zeichenketten ersetzt werden,
# sonst wird später das Ampersand etc. falsch erstzt.
s/\&darr;/§d§/g;
s/\&uarr;/§u§/g;
s/\&harr;/§h§/g;
s/\&#8597;/§v§/g;

# Evtl. schon in HTML-Form vorliegende Umlaute müssen temporär zurücküberstzt
# werden. (Wegen dem Ampersand.)
s/\&uuml;/u/g;
s/\&ouml;/ö/g;
s/\&auml;/ä/g;
s/\&Uuml;/Ü/g;
s/\&Ouml;/Ö/g;
s/\&Auml;/Ä/g;

s/\&gt;/>/g;
s/\&lt;/</g;

# ASCII -> HTML
s/&/\&amp;/g;
s/ä/\&auml;/g;
s/Ä/\&Auml;/g;
s/ü/\&uuml;/g;
s/Ü/\&Uuml;/g;
s/ö/\&ouml;/g;
s/Ö/\&Ouml;/g;
s/ß/\&szlig;/g;
s/"/\&quot;/g;

s/</\&lt;/g;
s/>/\&gt;/g;

# Kommentare bekommen eine andere Farbe.
# Alle '"', die wir einfügen, werden zuerst als §q§ eingefügt und erst ganz
# zum Schluss ersetzt, denn sonst können wir die '"' der Eingabedatei
# nicht von unseren unterscheiden.

# Clear branch buffer.
t dummy
: dummy
s/\/\//\<FONT color=§q§#00aa00§q§\>\/\//;
t InsTagEnd
b NoTagEnd

: InsTagEnd
s/$/\<\/FONT\>/;
: NoTagEnd

# Hier landen wir, wenn die Zeile kein Kommentar war und keine Strings enthält.
# Datentypen-highlight:
s/int[[:space:]][[:space:]]*/\<B\>\<FONT color=§q§#760096§q§\>int \<\/FONT\>\<\/B\>/g;
s/short[[:space:]][[:space:]]*/\<B\>\<FONT color=§q§#760096§q§\>short \<\/FONT\>\<\/B\>/g;
s/float[[:space:]][[:space:]]*/\<B\>\<FONT color=§q§#760096§q§\>float \<\/FONT\>\<\/B\>/g;
s/double[[:space:]][[:space:]]*/\<B\>\<FONT color=§q§#760096§q§\>double \<\/FONT\>\<\/B\>/g;
s/String[[:space:]][[:space:]]*/\<B\>\<FONT color=§q§#760096§q§\>String \<\/FONT\>\<\/B\>/g;
s/boolean[[:space:]][[:space:]]*/\<B\>\<FONT color=§q§#760096§q§\>boolean \<\/FONT\>\<\/B\>/g;

s/static[[:space:]][[:space:]]*/\<B\>\<FONT color=§q§#760096§q§\>static \<\/FONT\>\<\/B\>/g;
s/final[[:space:]][[:space:]]*/\<B\>\<FONT color=§q§#760096§q§\>final \<\/FONT\>\<\/B\>/g;

# Kontrollstrukturen highlight:
s/else[[:space:]][[:space:]]*if(/\<B\>else if\<\/B\>(/;
s/if(/\<B\>if\<\/B\>(/;
s/else[[:space:]]*{/\<B\>else \<\/B\>{/;
s/while(/\<B\>while\<\/B\>(/;
s/for(/\<B\>for\<\/B\>(/;
s/return/\<B\>return\<\/B\>/;
s/switch(/\<B\>switch\<\/B\>(/;
s/case/\<B\>case\<\/B\>/;

# Zum Schluss noch ein besonderes Leckerli: Wir Parsen auf Fehler,
# die man als C/C++/Java Programmierer gerne macht und weisen darauf hin.
s/++/\<FONT style=§q§background-color:#ffff00§q§\>++ not allowed in Jana\<\/FONT\>/g;
s/--/\<FONT style=§q§background-color:#ffff00§q§\>-- not allowed in Jana\<\/FONT\>/g;
s/-=/\<FONT style=§q§background-color:#ffff00§q§\>-= not allowed in Jana\<\/FONT\>/g;
s/+=/\<FONT style=§q§background-color:#ffff00§q§\>+= not allowed in Jana\<\/FONT\>/g;
s/\*=/\<FONT style=§q§background-color:#ffff00§q§\>\*= not allowed in Jana\<\/FONT\>/g;
s/\/=/\<FONT style=§q§background-color:#ffff00§q§\>\/= not allowed in Jana\<\/FONT\>/g;
s/\%=/\<FONT style=§q§background-color:#ffff00§q§\>\%= not allowed in Jana\<\/FONT\>/g;

# Alle §q§ durch " ersetzen. Das sind die ", die wir eingfügt haben.
s/\§q§/\"/g;

s/§d§/\&darr;/g;
s/§u§/\&uarr;/g;
s/§h§/\&harr;/g;
s/§v§/\&#8597;/g;

#$a <BR><BR><I>Jana syntax highlight generated by jana2html.sed</I>

# Zeile ausgeben.
p;